#!/bin/tcsh -f
#
# Martian Labs render submit script
#
# written by briank(at)martian-labs.com 6/28/2004
#
# This script generates a render command for drqueue (hacked for web tut)
#
#  ... yes, I know there are better ways of doing lots of this.
#      This is more production code than polished product code. ;o)
#
#

if ( ! ($?JOB) ) then
    echo 
    echo "    *** ERROR! ***"
    echo
    echo ' '\$JOB does not exist
    echo " Select a job first."
    echo ' '
    exit
endif

if ( ! ($?SHOT) ) then
    echo 
    echo "    *** ERROR! ***"
    echo
    echo ' '\$SHOT does not exist
    echo " Select a shot first."
    echo ' '
    exit
endif

if ($#argv < 1) then
	echo " "
	echo "Usage:  $0 <ifd_file_root>"
	echo " "
	exit
endif

set argv = ( `/usr/bin/getopt b:hv $*` )

set VERBOSITY = ""
set BIT_DEPTH = ""

foreach i ( $* )
    switch ( $i )
	case "-b"
	    shift
	    set BIT_DEPTH = "-b $1"
	    shift
	    breaksw
	case "-v"
	    shift
	    set VERBOSITY = "-V1a"
	    breaksw
	case "-h":
	    echo " "
	    echo "Usage:  $0 [options] <ifd_file_root>"
	    echo " "
	    echo " This script generates a render command for drqueue"
	    echo "  so you can make a new drqueue job"
	    echo " "
	    echo " Example: "
	    echo " "
	    echo "$0 ifd/foobar"
	    echo " "
	    echo "  evals to: "
	    echo " "
	    echo renderjob JobName\; rendershot ShotName\; mantra \< ifd/foobar.\$DRQUEUE_PADFRAME.ifd
	    echo " "
	    echo " Options:"
	    echo "  -b <depth> specify bit depth"
	    echo "  -v         turn on verbosity (-V1a)"
	    echo "  -h         this help text"
	    echo ' '
	    echo '\n'
	    exit
	    breaksw
    endsw
end

shift
set IFD = $1

echo renderjob $JOB:t\; rendershot $SHOT:t\; mantra $VERBOSITY $BIT_DEPTH \< $IFD.'$DRQUEUE_PADFRAME.ifd'

exit